從社會學(xué)實驗到行為仿真：理解基于Agent的觀點動力學(xué)建模思維

導(dǎo)語

觀點動力學(xué)（Opinion Dynamics）聚焦于個體初始觀點（通常以連續(xù)或離散變量表征）如何通過特定交互規(guī)則（如同群影響、權(quán)威服從）調(diào)整，并最終涌現(xiàn)出群體層面的觀點分布特征（如共識收斂、多陣營分化、極化加劇等），其核心目標(biāo)是揭示觀點演化的內(nèi)在規(guī)律，為理解社會輿論傳播、群體決策形成等現(xiàn)實問題提供可量化的理論工具。基于主體建模（Agent-based Modeling，ABM）為其提供了工具載體。作為一種自下而上的建模思維與方法，它既能通過具有自主屬性的 Agent 刻畫個體屬性，又能定義主體間的交互規(guī)則，模擬系統(tǒng)動態(tài)演化。其將個體的觀點屬性、互動模式等抽象為可計算規(guī)則，定義非線性復(fù)雜適應(yīng)系統(tǒng)環(huán)境，使觀點的分化、同化等過程在 “人工社會” 中具象呈現(xiàn)，進(jìn)而清晰揭示群體觀點從微觀互動到宏觀演化的內(nèi)在邏輯。

本文為你梳理了基于多主體進(jìn)行觀點動力學(xué)建模的思維脈絡(luò)：以理解群體交互對個體觀點的重要影響為起點，從現(xiàn)實情境中提煉主體屬性、交互規(guī)則、社會環(huán)境三類ABM建模核心要素，接著以DeGroot、Friedkin-Johnsen模型為例，展開符合初學(xué)者探索邏輯的ABM實操講解。最后，說明在更廣泛的科學(xué)研究問題中采用ABM方法的適用性。

如果你對這一話題感興趣，推薦給你目前集智正在進(jìn)行和兩個主題讀書會，歡迎你的加入。

關(guān)鍵詞：基于主體建模、非線性、復(fù)雜適應(yīng)系統(tǒng)、觀點動力學(xué)、自下而上建模

趙沐天丨作者

王朝會｜審校

ABM 是一種思維方式，而不僅僅是一門技術(shù)。 —— Eric Bonabeau[1]

1. 理解交互對觀點形成的重要影響

1951年的一天，所羅門·阿希（Solomon E. Asch）開展了一場社會心理學(xué)實驗。實驗開始時，參與者被帶入一個房間，被告知這是一場關(guān)于“視覺感知”的研究。房間里坐著七位“被試”，但真正的被試者并不知道，其余六人其實是實驗助手。研究人員拿出卡片，要求所有人依次指出右邊卡片上與左邊線段等長的線段。前兩輪測試，所有人都給出了正確答案。

線段判斷實驗

從第三輪測試開始，當(dāng)研究人員再次拿出卡片，助手們開始故意給出錯誤答案。在最后進(jìn)行選擇的真正被試者，面對群體一致的“錯誤”，會如何抉擇呢？實驗結(jié)果出乎意料：在12輪關(guān)鍵測試中，約75%的參與者至少有一次隨大流給出錯誤答案。阿希在1951、1956和1958年多次重復(fù)了這項系列實驗。結(jié)果表明：實驗全程始終堅持獨立判斷的人，僅占總?cè)藬?shù)的25%-35%。

阿希實驗揭示了群體交互對個體認(rèn)知的重要影響：人類的認(rèn)知并非絕對理性，在群體壓力下，我們會不自覺地調(diào)整判斷，甚至放棄親眼所見的事實（啟示1）。

接下來，試想如果選擇涉及道德抉擇，個體是否還會受到群體影響？

1963年，斯坦利·米爾格拉姆（Stanley Milgram）在耶魯大學(xué)展開實驗，意在探究“普通人在權(quán)威命令下能在多大程度上違背良心”。研究發(fā)現(xiàn)，65% 的普通人會在權(quán)威指令下突破道德底線，執(zhí)行他們認(rèn)為會造成傷害的行為。

共同地，這兩個實驗揭示了群體壓力的影響：群體影響的力量似乎遠(yuǎn)超我們的想象。在阿希實驗中，個體即便具備獨立做出正確判斷的能力，仍會在群體壓力下選擇遵從錯誤共識。在米爾格拉姆實驗中，當(dāng)權(quán)威指令與道德直覺發(fā)生沖突時，多數(shù)人選擇違背內(nèi)心準(zhǔn)則而持續(xù)服從權(quán)威指令（啟示2）。

不同之處在于，二者的實驗環(huán)境存在明顯差異：阿希實驗呈現(xiàn)的是扁平化的同群互動網(wǎng)絡(luò)，群體成員以平等身份形成共識壓力；而米爾格拉姆實驗則構(gòu)建了垂直化的權(quán)威層級結(jié)構(gòu)，清晰劃分出指令發(fā)出者與行為執(zhí)行者的角色定位（啟示3）。

雖然這些實驗結(jié)果表明了群體觀點對個人的顯著影響，但不可忽視的是：在阿希實驗中，即便群體壓力巨大，但仍有個體堅持獨立思考；米爾格拉姆實驗亦證實，道德認(rèn)知越健全的人，越能在權(quán)威指令與倫理良知的沖突中保持行為自主性。

基于此，我們可以再次得到三條啟示：個體是否選擇從眾，是多重心理因素綜合作用的結(jié)果（啟示4）；“固執(zhí)觀點”的存在，緩沖了群體極化現(xiàn)象（啟示5）；群體中的個體間存在差異，這種差異構(gòu)成了社會系統(tǒng)復(fù)雜性的微觀基礎(chǔ)（啟示6）。

群體交互對個體觀點的形成具有重要影響。為觀察和比較不同情境下的系統(tǒng)演化規(guī)律，可借助NetLogo等多主體建模工具，將群體壓力、個體差異等現(xiàn)實規(guī)則抽象為可計算的模型參數(shù)，在 “人工社會” 中模擬觀點傳播的動態(tài)過程，通過可視化結(jié)果探明群體影響的內(nèi)在機(jī)制。

上述6條啟示已經(jīng)幫助你自然地理解，為何交互機(jī)制、社會環(huán)境與主體屬性是建模的核心要素：啟示 1、2 指向交互機(jī)制設(shè)計，啟示 3 討論了社會環(huán)境的差異性，啟示 4-6 則涉及主體屬性對動態(tài)演化的影響。至此，你具備了基于主體建模方法進(jìn)行觀點動力學(xué)建模的基本邏輯認(rèn)識，即便此前對該領(lǐng)域全然陌生。

2. 用NetLogo實現(xiàn)觀點動力學(xué)建模

各類揭示群體觀點形成機(jī)制的社會心理學(xué)實驗為觀點動力學(xué)奠定了理論基礎(chǔ)。例如勒溫的場論、Sherif的光點實驗，以及上文提到的阿希線段判斷實驗和米爾格拉姆服從實驗。為辨識社會意識的交互規(guī)律，眾多觀點動力學(xué)線性模型作出了各類規(guī)則表達(dá)[2]。DeGroot模型以鄰居觀點的加權(quán)平均構(gòu)建交互規(guī)則。Friedkin-Johnsen模型在此之上，引入個體對初始觀點的堅持程度。Hegselmann-Krause等有界置信模型則設(shè)置了觀點交互閾值，刻畫相似觀點間的聚集傾向。選民模型等離散模型，則專注于二元觀點的演變。

隨著復(fù)雜網(wǎng)絡(luò)理論與統(tǒng)計物理方法的融入，觀點動力學(xué)被廣泛應(yīng)用于非線性復(fù)雜系統(tǒng)與網(wǎng)絡(luò)結(jié)構(gòu)耦合建模[3-5]，以刻畫群體觀點極化、聚類等復(fù)雜現(xiàn)象。采用ABM方法構(gòu)建觀點動力學(xué)模型，具有顯著契合性和獨特價值：

• 基于主體建模為為理解復(fù)雜性（complexity）問題提供了有效路徑。自下而上的建模邏輯能夠通過自組織（self-organization）過程產(chǎn)生涌現(xiàn)（emergence）現(xiàn)象，并支持對系統(tǒng)演化過程的動態(tài)觀測，為解析群體觀點的形成機(jī)制提供了直觀視角。

• 通過對個體互動過程的刻畫，基于主體建模將復(fù)雜社會場景中的觀點交互問題抽象為簡化規(guī)則，構(gòu)造復(fù)雜適應(yīng)系統(tǒng)（Complex Adaptive System，CAS），揭示微觀行為與宏觀現(xiàn)象的內(nèi)在關(guān)聯(lián)。

• 建模方法能夠針對不同情境下的群體觀點演化問題展開分析與討論，實現(xiàn)對問題的理解、定義、量化、可視化與仿真，為多樣化現(xiàn)實情境的模擬與預(yù)測提供支撐。

如今，數(shù)據(jù)驅(qū)動與多主體建模的融合成為重要發(fā)展方向[6,7]。隨著深度學(xué)習(xí)、大模型與網(wǎng)絡(luò)分析交叉應(yīng)用的不斷深入，有望在輿論趨勢預(yù)測等實際場景中實現(xiàn)更精準(zhǔn)的動態(tài)建模。

接下來，我們將以DeGroot和Friedkin-Johnsen這兩個經(jīng)典的觀點動力學(xué)模型為例，層層拆解現(xiàn)實問題，逐步理解基于Agent的觀點動力學(xué)建模邏輯，把復(fù)雜的社交場景「翻譯」成模型里的規(guī)則代碼！

2.1 實現(xiàn)模型的基本規(guī)則

在DeGroot模型中，群體成員在初始狀態(tài)下持有差異化觀點傾向（以連續(xù)變量表示）。每次調(diào)整觀點時，個體都會「完全聽周圍人的意見」，把別人的想法按信任程度加權(quán)平均，再變成自己的新想法。而Friedkin-Johnsen模型在更新個體觀點時，保留了一部分「個性態(tài)度」，另一部分則是周圍人的意見加權(quán)平均。

DeGroot 模型可以用來描述現(xiàn)實情境中以群體共識為導(dǎo)向的交流狀態(tài)。例如，食品安全事件引發(fā)輿情傳播，信息在社交網(wǎng)絡(luò)中快速流動，公眾形成對事件的共識性判斷；在公共衛(wèi)生知識的普及過程中，社會逐步統(tǒng)一對科學(xué)方法的認(rèn)識；團(tuán)隊成員為推進(jìn)項目，通過充分交流凝聚執(zhí)行方案。但是，在社會輿論中，個體帶有初始觀念、難以完全受到社會環(huán)境影響的情境廣泛存在。例如，因為品牌忠誠度、消費習(xí)慣等屬性存在差異，所以不同消費者對品牌營銷事件的反應(yīng)可能有所不同；跨部門協(xié)作中，不同團(tuán)隊雖會努力相互配合，卻始終關(guān)注自身角色利益。為描述該問題，F(xiàn)riedkin-Johnsen模型應(yīng)運而生，用于表達(dá)這些情境里個體保留認(rèn)知差異，同時又受到群體影響的狀態(tài)。

第一步，讓我們根據(jù)DeGroot和Friedkin-Johnsen模型的基本原理，依據(jù)交互機(jī)制、社會環(huán)境與主體屬性三個建模要素，將模型思想轉(zhuǎn)化為建模規(guī)則。

• 交互機(jī)制：在這里，設(shè)置每個主體通過交互半徑識別周圍鄰居；使用指數(shù)衰減函數(shù)計算與鄰居的連接強(qiáng)度，采用加權(quán)平均規(guī)則考慮鄰居影響，距離越近權(quán)重越高。

• 社會環(huán)境規(guī)則：設(shè)置主體空間內(nèi)均勻分布，形成空間依賴的交互網(wǎng)絡(luò)。

• 主體屬性：采用連續(xù)值(0-1)表示觀點傾向(正面-負(fù)面)。設(shè)置觀點越正面，主體顏色越淺；觀點越負(fù)面，主體顏色越深。根據(jù)模型要求，主體觀點更新規(guī)則為，鄰居權(quán)重矩陣需滿足；若不考慮個性觀點權(quán)重， α =0，體現(xiàn)的是DeGroot模型規(guī)則；若 α≠0，則體現(xiàn)Friedkin-Johnsen模型規(guī)則。

下面是一個完整的NetLogo示例代碼（使用NetLogo 6.3.0編寫）：

globals [
  num-agents          ;; 主體數(shù)量
  neighbor-radius     ;; 鄰居識別半徑
  step-counter        ;; 時間步計數(shù)器
]

turtles-own [
  opinion             ;; 主體觀點 (0-1)
  self-weight         ;; 自身權(quán)重
  neighbor-weights    ;; 鄰居及其對應(yīng)權(quán)重的關(guān)聯(lián)列表
]

to setup
  clear-all
  reset-ticks

  ;; 參數(shù)初始化
  set num-agents 200
  set neighbor-radius 5
  set step-counter 0

  ;; 創(chuàng)建主體（均勻分布）
  create-turtles num-agents [
    set shape "circle"
    set size 1.5

    ;; 隨機(jī)位置與觀點
    setxy random-xcor random-ycor
    set opinion random-float 1  ;; 均勻分布的初始觀點
    update-weights  ;; 初始化權(quán)重
    update-color    ;; 根據(jù)觀點設(shè)置顏色
  ]
end

to update-weights
  ;; 清空并重新計算所有權(quán)重
  set self-weight 0.2  ;; 自身權(quán)重
  set neighbor-weights []  ;; 鄰居權(quán)重列表

  ;; 獲取鄰居代理集（排除自身）
  let my-neighbors other turtles in-radius neighbor-radius
  let neighbor-total-weight 0
  let neighbor-list sort my-neighbors

  ;; 計算鄰居權(quán)重（不包括自身）
  foreach neighbor-list [ n ->
    let dist distance n
    let w exp (-5 * dist)  ;; 指數(shù)衰減函數(shù)計算權(quán)重
    set neighbor-weights lput (list n w) neighbor-weights
    set neighbor-total-weight neighbor-total-weight + w
  ]

  ;; 歸一化鄰居權(quán)重（使鄰居權(quán)重總和為1）
  let normalized-neighbor-weights []
  foreach neighbor-weights [ pair ->
    let neighbor item 0 pair
    let weight item 1 pair
    set normalized-neighbor-weights lput (list neighbor (weight / neighbor-total-weight)) normalized-neighbor-weights
  ]

  set neighbor-weights normalized-neighbor-weights
end

to update-color
  ;; 觀點越正向（接近1），顏色接近淺藍(lán)色
  ;; 觀點越負(fù)面（接近0），顏色接近深藍(lán)色
  set color scale-color blue opinion 0 1
end

to go
  if not any? turtles [ stop ]

  ;; 更新權(quán)重并計算新觀點
  ask turtles [
    update-weights
    let new-op 0

    ;; 自身觀點貢獻(xiàn)
    set new-op new-op + self-weight * opinion

    ;; 所有鄰居觀點的加權(quán)貢獻(xiàn)
    let neighbor-influence 0
    foreach neighbor-weights [ pair ->
      let neighbor item 0 pair
      let weight item 1 pair
      set neighbor-influence neighbor-influence + weight * [opinion] of neighbor
    ]
    set new-op new-op + (1 - self-weight) * neighbor-influence

    set opinion new-op
    update-color  ;; 更新顏色映射
  ]

  set step-counter step-counter + 1
  tick
End

你可以試著調(diào)整模型里的參數(shù)，比如不同個性觀點的權(quán)重（self-weight）、群體規(guī)模大小（num-agents）等，看看這些因素會對觀點演化的特點和速度產(chǎn)生怎樣的影響。

觀察模擬過程會發(fā)現(xiàn)，雖然已經(jīng)實現(xiàn)了觀點演化的過程，但好像沒辦法讓整個群體快速達(dá)成觀點統(tǒng)一。目前的群體觀點分裂成幾個“陣營”，形成了小范圍的觀點同化現(xiàn)象。

基本模型

2.2 實現(xiàn)主體的空間移動：改變主體社交范圍

思考原因，很可能是因為社交關(guān)系固定不變，才導(dǎo)致形成了多個觀點團(tuán)體。如果想要實現(xiàn)整個群體的觀點統(tǒng)一，是不是可以試試讓成員的社交圈“流動”起來，在更大的范圍內(nèi)互相交換想法呢？

我們可以把這個思路抽象成具體規(guī)則，并用代碼實現(xiàn)：在程序的運行模塊里，給turtles（角色主體）增加移動的屬性設(shè)置。

fd 1            ;; 向前移動1單位距離
rt random 360   ;; 隨機(jī)轉(zhuǎn)向  

我們可以發(fā)現(xiàn)，通過這個簡單的改動，群體逐漸形成了統(tǒng)一的觀點！

改變主體的社交范圍

2.3 調(diào)整主體的態(tài)度屬性：實現(xiàn)群體觀點傾向性

在剛剛的代碼里，我們把群體成員的觀點設(shè)置成了從0到1的均勻分布。但在現(xiàn)實生活中，群體對特定事件的觀點通常會有一定的傾向性。接下來，我們可以繼續(xù)調(diào)試代碼，通過設(shè)置群體觀點的偏態(tài)分布規(guī)則，來模擬這種現(xiàn)象。

添加觀點偏態(tài)分布模塊：

to-report biased-random
  let x random-normal 0.25 0.2
  if x < 0 [ set x 0 ]
  if x > 1 [ set x 1 ]
  report x
End

這段代碼采用的實現(xiàn)方式是，讓觀點均值為0.25，標(biāo)準(zhǔn)差設(shè)為0.2，這樣能呈現(xiàn)出偏向消極且?guī)в幸欢ǜ涌臻g的分布，同時還能保證所有樣本都處于0到1的范圍內(nèi)。不過，實現(xiàn)這一目標(biāo)并非只有這一種途徑，你還可以嘗試其它方法。

然后，在setup中調(diào)用該模塊：

set opinion biased-random

此時，群體觀點的傾向性很明顯。但是，在主體社交范圍固定時，仍然有機(jī)會出現(xiàn)持有積極觀點的小型團(tuán)體。

觀點偏態(tài)分布 固定社交范圍

當(dāng)個體逐漸改變社交范圍時，群體觀點同樣逐漸同化，相較于觀點均勻分布時的群體觀點穩(wěn)態(tài)，更加偏向消極。

同時，我們還可以發(fā)現(xiàn)，在同一套參數(shù)設(shè)置下進(jìn)行多次實驗，群體觀點總能演化至同一水平。這表明，模型對輿論觀點狀態(tài)可以進(jìn)行穩(wěn)定預(yù)測。

觀點偏態(tài)分布 主體流動交互

2.4 添加主體異質(zhì)性：體現(xiàn)不同主體的獨立思考能力差異

在上述模型中，假設(shè)所有主體都擁有相同的個性決策權(quán)重。但在現(xiàn)實生活中，不同個體的獨立思考能力往往具有差異。我們可以添加主體異質(zhì)性規(guī)則模擬這一現(xiàn)象，這也是 NetLogo 非常擅長的工作。

下面我們來添加一個生成異質(zhì)性個性決策權(quán)重的函數(shù)：

to-report generate-self-weight
  let w random-normal 0.5 0.2
  if w < 0.1 [ set w 0.1 ]
  if w > 0.9 [ set w 0.9 ]
  report w
end

這段代碼通過正態(tài)分布來生成處于0.1-0.9范圍的個體觀點權(quán)重，這里設(shè)定均值為0.5，標(biāo)準(zhǔn)差為0.2，如此一來，就能保證每個主體的獨立思考能力具有差異。

同樣，在setup中完成初始化即可：

set self-weight generate-self-weight

請你在不同模型情境和參數(shù)設(shè)置下觀察異質(zhì)性主體的表現(xiàn)，看看可以得到什么啟示？

現(xiàn)在，你已經(jīng)明白了如何從生活中常見的場景入手，將這些現(xiàn)實問題轉(zhuǎn)化為建模規(guī)則。接下來，你可以獨立嘗試自己感興趣的話題，并通過數(shù)據(jù)輸出結(jié)果或可視化圖表來觀察參數(shù)調(diào)整的效果。

3. 構(gòu)造人工社會的核心思維

阿希實驗與米爾格拉姆實驗揭示了群體壓力扭曲個體理性的驚人表現(xiàn)。但不容忽視的是，社會交互又是維系社會協(xié)作的神經(jīng)中樞，涌現(xiàn)出超越個體認(rèn)知的宏觀秩序，驅(qū)動群體智慧演化。

以觀點動力學(xué)建模為范例，我們能夠洞悉構(gòu)造人工社會的核心思維——主體屬性、交互規(guī)則與社會環(huán)境，實現(xiàn)從現(xiàn)實問題到模型規(guī)則的轉(zhuǎn)化。

或許你已萌生運用ABM方法探索科學(xué)問題的熱忱。在此，筆者有幾點建議，幫助你明晰該方法的適用性。首先，需判斷待研究的科學(xué)問題是否屬于“交互驅(qū)動型”。從研究方法論而言，理解交互規(guī)則是構(gòu)建復(fù)雜適應(yīng)性系統(tǒng)的邏輯起點，也是開展相關(guān)研究的必要前提。其次，復(fù)雜秩序往往源自簡單主體的自適應(yīng)交互過程，這要求研究者有針對性地建構(gòu)主體屬性與社會環(huán)境，建立恰當(dāng)?shù)某橄笠?guī)則體系。并非所有社會現(xiàn)象都需引入主體異質(zhì)性假設(shè)，“全知全能”的個體屬性也并非人工社會模型追求的目標(biāo)。另外，建模邏輯不是追求對系統(tǒng)的“全局操控”或細(xì)節(jié)設(shè)計，而是通過規(guī)則設(shè)計激發(fā)系統(tǒng)的自組織演化能力。

盡管當(dāng)前Python庫已支持調(diào)用包括觀點動力學(xué)模型在內(nèi)的多種建模工具，但我們?nèi)孕枰ㄟ^自主編碼實踐，深度理解復(fù)雜適應(yīng)系統(tǒng)建模的核心邏輯。通過掌握建模思維，你可以用代碼自由驗證腦海中靈光乍現(xiàn)的猜想，將探索的觸角延伸至現(xiàn)實社會難以觸及的夢幻，探索無限的可能性。那些掙脫常規(guī)范式的獨立思辨，正是激發(fā)群體智慧涌現(xiàn)的密鑰。

參考文獻(xiàn)

[1] Bonabeau E. Agent-based modeling: Methods and techniques for simulating human systems [J]. Proceedings of the National Academy of Sciences, 2002, 99(suppl_3): 7280-7287.

[2] Wen T, Zheng R, Wu T, et al. Formulating opinion dynamics from belief formation, diffusion and updating in social network group decision-making: Towards developing a holistic framework [J]. European Journal of Operational Research, 2025, 325(3): 381-399.

[3] Shen Y, Ma X, Deveci M, et al. A hybrid opinion dynamics model with leaders and followers fusing dynamic social networks in large-scale group decision-making [J]. Information Fusion, 2025, 116: 102799.

[4] Xu Y, Liu S, Cheng T C E, et al. Opinion convergence and management: Opinion dynamics in interactive group decision-making [J]. European Journal of Operational Research, 2025, 323(3): 938-951.

[5] Yang Y, Li H, Gao S, et al. Interdependent evolutionary dynamics of opinion and strategy on two-layer networks [J]. Chaos, Solitons & Fractals, 2025, 191: 115933.

[6] Ding G, Liu Z, Li S, et al. Impact of mindset types and social community compositions on opinion dynamics: A large language model-based multi-agent simulation study [J]. Computers in Human Behavior, 2025, 172: 108730.

[7] Wang Y, Li X, Cheng Y, et al. A neural probabilistic bounded confidence model for opinion dynamics on social networks [J]. Expert Systems with Applications, 2024, 247: 123315.

參考文獻(xiàn)可上下滑動查看

AI×傳播讀書會

在AI快速發(fā)展的當(dāng)下，AI不僅深刻影響著信息傳播的方式，也為傳播學(xué)研究帶來了全新視角和方法。基于此，集智俱樂部聯(lián)合北京師范大學(xué)許小可教授、浙江大學(xué)張子柯教授、南京大學(xué)王成軍教授、深圳大學(xué)廖好副教授共同發(fā)起，從計算敘事、智能傳播、人機(jī)傳播與傳播仿真四個板塊向來共同探索AI與傳播的前沿交叉，來深度理解傳播機(jī)制和傳播生態(tài)。讀書會自8月23日起，每周六10:00-12:00舉行，預(yù)計持續(xù)12周。歡迎掃碼加入，共建“AI×傳播”社區(qū)。

詳情請見：

1.

2.

3.

4.

5.

6.

7.